首页 | 心情日记 | 建站心得 | 编程技术 | 大盘分析 | 股市信息 | 学习园地 | 电脑技巧 | 物流外贸 | 另类其它 | 站长推荐 | 给我留言 | 相册

用户登陆
用户:
密码:
 
不保存保存一天
保存一月保存一年

站点日历
73 2020 - 10 48
    123
45678910
11121314151617
18192021222324
25262728293031


站点统计

最新评论

日志搜索

 标题   内容


XMLHTTP和ServerXMLHTTP 超时的判断 ASP连接11种数据库语法总结
未知 用于Asp的base64编码/解码函数   [ 日期:2010-03-09 21:10:58 ]   [ 来自:艾恩ASP学习BLOG ]

海外邮件中继,海外退信中继,美国高速VPS,不限流量VPN,邮局维护和管理,邮件网关,EMOS邮件中继,POSTFIX邮件中继,Winwebmail邮件中继,Winmail邮件中继,DBMail邮件中继,JDMail邮件中继,Exchange邮件中继,MDaemon邮件中继 淘宝店:http://shantan.taobao.com 云邮科技官网:www.yunrelay.com

【字体设置:
网上很多关于base64编/解码的代码,找到的这个是最好的了,有个不尽人意的地方是--编/解码调用一堆函数,我给增加了2个函数用来编/解码,调用方法:
将第二段代码保存到base64.inc,在需要编码的页面将base64.inc包含进来,调用相应函数即可,例如
<!--#include file="base64.inc"-->
<%
'---------------------------------------------------------------------------------
str="我爱你tandy"
encodestr=encode64(str) '编码
response.write encodestr & "<hr>"
response.write decode64(encodestr) & "<hr>" '解码
%>
代码段二:
<%
sBASE_64_CHARACTERS = "ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz0123456789+/"
sBASE_64_CHARACTERS = strUnicode2Ansi(sBASE_64_CHARACTERS)

'计算unicode字符串的Ansi编码的长度
Function strUnicodeLen(asContents)
 '计算unicode字符串的Ansi编码的长度
 asContents1="a"&asContents
 len1=len(asContents1)
 k=0
 for i=1 to len1
  asc1=asc(mid(asContents1,i,1))
  if asc1<0 then asc1=65536+asc1
  if asc1>255 then
   k=k+2
  else
   k=k+1
  end if
 next
 strUnicodeLen=k-1
End Function

'将Unicode编码的字符串,转换成Ansi编码的字符串
Function strUnicode2Ansi(asContents)
 '将Unicode编码的字符串,转换成Ansi编码的字符串
 strUnicode2Ansi=""
 len1=len(asContents)
 for i=1 to len1
  varchar=mid(asContents,i,1)
  varasc=asc(varchar)
  if varasc<0 then varasc=varasc+65536
  if varasc>255 then
   varHex=Hex(varasc)
   varlow=left(varHex,2)
   varhigh=right(varHex,2)
   strUnicode2Ansi=strUnicode2Ansi & chrb("&H" & varlow ) & chrb("&H" & varhigh )
  else
   strUnicode2Ansi=strUnicode2Ansi & chrb(varasc)
  end if
 next
End function

'将Ansi编码的字符串,转换成Unicode编码的字符串
Function strAnsi2Unicode(asContents)
 '将Ansi编码的字符串,转换成Unicode编码的字符串
 strAnsi2Unicode = ""
 len1=lenb(asContents)
 if len1=0 then exit function
 for i=1 to len1
  varchar=midb(asContents,i,1)
  varasc=ascb(varchar)
  if varasc > 127 then
   strAnsi2Unicode = strAnsi2Unicode & chr(ascw(midb(asContents,i+1,1) & varchar))
   i=i+1
  else
   strAnsi2Unicode = strAnsi2Unicode & chr(varasc)
  end if
 next
End function

'将Ansi编码的字符串进行Base64编码
Function Base64encode(asContents)
 '将Ansi编码的字符串进行Base64编码
 'asContents应当是ANSI编码的字符串(二进制的字符串也可以)
 Dim lnPosition
 Dim lsResult
 Dim Char1
 Dim Char2
 Dim Char3
 Dim Char4
 Dim Byte1
 Dim Byte2
 Dim Byte3
 Dim SaveBits1
 Dim SaveBits2
 Dim lsGroupBinary
 Dim lsGroup64
 Dim m4,len1,len2

 len1=Lenb(asContents)
 if len1<1 then
  Base64encode=""
  exit Function
 end if

 m3=Len1 Mod 3
 If M3 > 0 Then asContents = asContents & String(3-M3, chrb(0))
 '补足位数是为了便于计算
 IF m3 > 0 THEN
  len1=len1+(3-m3)
  len2=len1-3
 else
  len2=len1
 end if
 lsResult = ""
 For lnPosition = 1 To len2 Step 3
  lsGroup64 = ""
  lsGroupBinary = Midb(asContents, lnPosition, 3)
  
  Byte1 = Ascb(Midb(lsGroupBinary, 1, 1)): SaveBits1 = Byte1 And 3
  Byte2 = Ascb(Midb(lsGroupBinary, 2, 1)): SaveBits2 = Byte2 And 15
  Byte3 = Ascb(Midb(lsGroupBinary, 3, 1))
  
  Char1 = Midb(sBASE_64_CHARACTERS, ((Byte1 And 252) \ 4) + 1, 1)
  Char2 = Midb(sBASE_64_CHARACTERS, (((Byte2 And 240) \ 16) Or (SaveBits1 * 16) And &HFF) + 1, 1)
  Char3 = Midb(sBASE_64_CHARACTERS, (((Byte3 And 192) \ 64) Or (SaveBits2 * 4) And &HFF) + 1, 1)
  Char4 = Midb(sBASE_64_CHARACTERS, (Byte3 And 63) + 1, 1)
  lsGroup64 = Char1 & Char2 & Char3 & Char4
   
  lsResult = lsResult & lsGroup64
 Next
  
 '处理最后剩余的几个字符
 if M3 > 0 then
  lsGroup64 = ""
  lsGroupBinary = Midb(asContents, len2+1, 3)
  
  Byte1 = Ascb(Midb(lsGroupBinary, 1, 1)): SaveBits1 = Byte1 And 3
  Byte2 = Ascb(Midb(lsGroupBinary, 2, 1)): SaveBits2 = Byte2 And 15
  Byte3 = Ascb(Midb(lsGroupBinary, 3, 1))
  
  Char1 = Midb(sBASE_64_CHARACTERS, ((Byte1 And 252) \ 4) + 1, 1)
  Char2 = Midb(sBASE_64_CHARACTERS, (((Byte2 And 240) \ 16) Or (SaveBits1 * 16) And &HFF) + 1, 1)
  Char3 = Midb(sBASE_64_CHARACTERS, (((Byte3 And 192) \ 64) Or (SaveBits2 * 4) And &HFF) + 1, 1)
   
  if M3=1 then
   lsGroup64 = Char1 & Char2 & ChrB(61) & ChrB(61) '用=号补足位数
  else
   lsGroup64 = Char1 & Char2 & Char3 & ChrB(61) '用=号补足位数
  end if
   
  lsResult = lsResult & lsGroup64
 end if
  
 Base64encode = lsResult  
End Function

'将Base64编码字符串转换成Ansi编码的字符串
Function Base64decode(asContents)
 '将Base64编码字符串转换成Ansi编码的字符串
 'asContents应当也是ANSI编码的字符串(二进制的字符串也可以)
 Dim lsResult
 Dim lnPosition
 Dim lsGroup64, lsGroupBinary
 Dim Char1, Char2, Char3, Char4
 Dim Byte1, Byte2, Byte3
 Dim M4,len1,len2
 
 len1= Lenb(asContents)
 M4 = len1 Mod 4
 
 if len1 < 1 or M4 > 0 then
  '字符串长度应当是4的倍数
  Base64decode = ""
  exit Function
 end if

 '判断最后一位是不是 = 号
 '判断倒数第二位是不是 = 号
 '这里m4表示最后剩余的需要单独处理的字符个数
 if midb(asContents, len1, 1) = chrb(61) then m4=3
 if midb(asContents, len1-1, 1) = chrb(61) then m4=2
 
 if m4 = 0 then
  len2=len1
 else
  len2=len1-4
 end if

 For lnPosition = 1 To Len2 Step 4
  lsGroupBinary = ""
  lsGroup64 = Midb(asContents, lnPosition, 4)
  Char1 = InStrb(sBASE_64_CHARACTERS, Midb(lsGroup64, 1, 1)) - 1
  Char2 = InStrb(sBASE_64_CHARACTERS, Midb(lsGroup64, 2, 1)) - 1
  Char3 = InStrb(sBASE_64_CHARACTERS, Midb(lsGroup64, 3, 1)) - 1
  Char4 = InStrb(sBASE_64_CHARACTERS, Midb(lsGroup64, 4, 1)) - 1
  Byte1 = Chrb(((Char2 And 48) \ 16) Or (Char1 * 4) And &HFF)
  Byte2 = lsGroupBinary & Chrb(((Char3 And 60) \ 4) Or (Char2 * 16) And &HFF)
  Byte3 = Chrb((((Char3 And 3) * 64) And &HFF) Or (Char4 And 63))
  lsGroupBinary = Byte1 & Byte2 & Byte3

  lsResult = lsResult & lsGroupBinary
 Next

 '处理最后剩余的几个字符
 if M4 > 0 then
  lsGroupBinary = ""
  lsGroup64 = Midb(asContents, len2+1, m4) & chrB(65) 'chr(65)=A,转换成值为0
  if M4=2 then '补足4位,是为了便于计算
   lsGroup64 = lsGroup64 & chrB(65)
  end if
  Char1 = InStrb(sBASE_64_CHARACTERS, Midb(lsGroup64, 1, 1)) - 1
  Char2 = InStrb(sBASE_64_CHARACTERS, Midb(lsGroup64, 2, 1)) - 1
  Char3 = InStrb(sBASE_64_CHARACTERS, Midb(lsGroup64, 3, 1)) - 1
  Char4 = InStrb(sBASE_64_CHARACTERS, Midb(lsGroup64, 4, 1)) - 1
  Byte1 = Chrb(((Char2 And 48) \ 16) Or (Char1 * 4) And &HFF)
  Byte2 = lsGroupBinary & Chrb(((Char3 And 60) \ 4) Or (Char2 * 16) And &HFF)
  Byte3 = Chrb((((Char3 And 3) * 64) And &HFF) Or (Char4 And 63))

  if M4=2 then
   lsGroupBinary = Byte1
  elseif M4=3 then
   lsGroupBinary = Byte1 & Byte2
  end if

  lsResult = lsResult & lsGroupBinary
 end if

 Base64decode = lsResult

End Function

function encode64(byval str)
        encode64=strAnsi2Unicode(Base64encode(strUnicode2Ansi(str)))
end function

function decode64(byval str)
        decode64=strAnsi2Unicode(Base64decode(strUnicode2Ansi(str)))
end function
%>

暂时没有评论
   发表评论 - 不要忘了输入验证码哦!
作者: 用户:  密码:  我要注册 验证码: 
为防止广告注册机程序,验证码不会自动显示,请点击此处显示或者(刷新)验证码!
评论:

禁止表情
禁止UBB
禁止图片
识别链接
识别关键字
确定发布?
最多可以输入200个字,目前你已经输入了0个字;你今日还可以发表10条评论!
点这里显示QQ表情【隐藏是为了加快网页打开速度】
 
   

CopyRight © 2008-2010 广东金融学院030904班 All Rights Reserved
Powered by www.030904.com